Build: enable ktlint+detekt, format sources, add core unit tests

buildSrc/src/main/kotlin/lms.lint.gradle.kts

@@ -0,0 +1,34 @@
+// Единая конфигурация статического анализа Kotlin: ktlint (формат) + detekt (качество).
+// На время миграции ignoreFailures=true — задачи только отчитываются, не ломая сборку.
+import io.gitlab.arturbosch.detekt.Detekt
+
+plugins {
+    id("org.jlleitschuh.gradle.ktlint")
+    id("io.gitlab.arturbosch.detekt")
+}
+
+ktlint {
+    ignoreFailures.set(true)
+    filter {
+        exclude("**/build/**")
+    }
+}
+
+detekt {
+    buildUponDefaultConfig = true
+    config.setFrom(rootProject.files("config/detekt/detekt.yml"))
+    ignoreFailures = true
+    parallel = true
+}
+
+tasks.withType<Detekt>().configureEach {
+    jvmTarget = "21"
+    exclude("**/build/**")
+    reports {
+        html.required.set(true)
+        xml.required.set(false)
+        txt.required.set(false)
+        sarif.required.set(false)
+        md.required.set(false)
+    }
+}

buildSrc/src/main/kotlin/lms.spring-boot.gradle.kts

@@ -6,6 +6,7 @@ plugins {
     id("org.jetbrains.kotlin.plugin.spring")
     id("org.jetbrains.kotlin.plugin.jpa")
     id("org.springframework.boot")
+    id("lms.lint")
 }
 
 group = "ru.ysu.lms"

buildSrc/src/main/kotlin/lms.spring-library.gradle.kts

@@ -4,6 +4,7 @@ import org.gradle.api.tasks.testing.logging.TestLogEvent
 plugins {
     kotlin("jvm")
     id("org.jetbrains.kotlin.plugin.spring")
+    id("lms.lint")
 }
 
 group = "ru.ysu.lms"